appleii

라자루스 첫 설치 후 에디터 세팅하기

appleii — Sun, 16 Jan 2022 21:31:40 +0900

라자루스를 처음 설치하면 에디터의 기본세팅이 마음에 들지 않아서 변경하고 싶을 때가 있다. 몇가지 변경 사항을 알아본다.

메인메뉴에서 Tools->Options 를 선택한다.

1. 탭 8칸 -> 2칸, 4칸 변경

Editor -> General -> Tab and Indent 를 선택하여 제일 위에 있는 Smart Tabs 를 체크해제한다. 오른쪽의 Tab widths 를 자신의 취향에 맞게 설정한다.

2. Completion and hints 반응속도 0 으로 변경

Editor -> Competion and Hints 를 선택한다.

오른쪽의 슬라이드 바가 3개 있다.

- Delay for completion box
  코드를 자동 완성 시켜주는 박스가 뜨는 속도를 조절해준다.
예를 들어 Button1 의 Caption 을 변경시키고 싶다면 Button1 을 누르고 점(.)을 누르면 자동으로 선택할 수 있는 메소드나 프라퍼티가 나타난다.

- Delay for hints
  코드 에디터에서 특정키워드 위에 마우스 커서를 위치시키면 해당 키워드의 정의와 정의된 곳의 위치를 알려준다.

- Delay for long line hints in completion box
  Completion Box 의 크기는 고정되어 있기 때문에 메소드나 프라퍼티의 이름이 길다면 박스 크기에 맞게 잘려 나간다. 위아래 화살표 키로 해당 위치로 이동하면 라인 전부를 보여준다. 라인전체를 보여줄때까지의 시간이다.

3. := 조정

기본 세팅에서는 ':=' 앞뒤에 스페이스가 자동완성되지 않는다.
Codetools -> Space 를 선택한다. 오른쪽의 Insert space in front of 에서 Symbol 을 체크한다. Insert space after 에도 Symbol 을 체크한다.

화면에서 보이는 것처럼 ' := ' 와 같이 앞뒤로 스페이스가 적용된다.

4. Outline 그리기

같은 블럭을 표시하는 Outline을 그려준다.

5. Visual Studio Code Dark Color Theme 적용하기

에디터에 비주얼 스튜디오 코드 다크 테마를 적용할 수 있다.
컬러테마를 다운로드 한 뒤에 C:\Users\사용자이름\AppData\Local\lazarus\userschemes 위치에 복사한다. 사용자이름에는 현재 사용하는 윈도우 사용자 이름으로 바꾸면 된다.

vsclaz_theme.xml

0.05MB

https://github.com/assisdantas/vsclaz_theme

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (5) 엑셀파일 출력 II

appleii — Mon, 23 Aug 2021 16:48:45 +0900

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (1) 폼 디자인
라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (2) 데이터베이스
라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (3) 기타기능
라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (4) 엑셀파일 출력 I
라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (5) 엑셀파일 출력 II

데이터베이스를 엑셀 파일로 출력하는 것에 성공했지만, 마음에 들지 않는 점이 있다. 실행화면에 표시되는 DBGrid 의 데이터와 일치하지 않는 것이다.

[ DBGrid 에서의 필드이름 ]

[ 엑셀파일에서의 필드이름 ]

데이터베이스와 DBGrid 에 표시되는 데이터에는 차이가 있다. 데이터베이스에는 PK 필드가 있지만 DBGrid 에는 표시되지 않는다. 그리고 데이터베이스의 필드이름은 영어로 표시되어 있지만 , DBGrid 의 필드에는 별도의 캡션이 표시된다. FPSExport 에서 제공하는 내보내기(Export) 프로시져들은 기본적으로 데이터베이스 내용 그대로 내보내는 것을 전제로 하고 있다. DBGrid 에 표시되는 모습 그대로 엑셀 파일로 출력하려면 어떻게 해야 할까.

엑셀 문서는 한개의 페이지가 WorkSheet , WorkSheet 가 여러개 모여서 WorkBook 으로 구성된다. WorkSheet 내의 한개의 칸은 Cell 이라고 부른다. WorkBook 을 Create 하고 WorkSheet 를 Add 하면 한개의 엑셀 문서가 완성된다. uses 에 fpspreadsheet 와 fpstypes 를 추가시키고 다음 문장을 입력하면 문서가 만들어진다.

Book := TsWorkBook.Create;
Sheet := Book.AddWorksheet('비밀번호 관리');

엑셀 문서를 만들고 그 내부에 구현해야 하는 기능은 다음과 같다.

- DBGrid 컬럼의 [Visible] Property 가 True 일 때만 엑셀파일로 출력
- DBGrid 컬럼의 캡션을 엑셀파일의 첫행에 출력

[ DBGrid Column 이 Visible = False ]

DBGrid 의 Column 이 Visible 일 때만 엑셀문서에 쓰기한다. 첫행은 DBGrid 의 Caption 을 WriteText 한다. DBGrid 의 Column 이 Visible 일 때만 VisCol 을 1 증가시켜서 엑셀문서의 Column 을 증가시키는 원리를 주목해보자.

 
for Col := 0 to ADataSet.Fields.Count - 1 do
begin
  if AGrid.Columns[Col].Visible then ////DBGrid 의 컬럼이 Visible 일 때만 진행한다.
  begin
    Cell := Sheet.WriteText(Row, VisCol, AGrid.Columns[Col].Title.Caption);
    Sheet.WriteBackgroundColor(cell, clMoneyGreen); //첫 행의 배경색
    VisCol := VisCol + 1;
  end;
end;

전체코드는 다음과 같다.

 
procedure TMainForm.ExportDBGridToExcel(AGrid: TDBGrid; AFileName: String);
var
  Book: TsWorkBook;
  Sheet: TsWorkSheet;
  Row, Col, VisCol: Integer;
  Cell: PCell;
  ADataSet: TDataSet;
  Field: TField;
begin
  ADataSet := AGrid.DataSource.DataSet;
  Book := TsWorkBook.Create;
  Sheet := Book.AddWorksheet('비밀번호 관리');
  Row := 0; Col := 0; VisCol := 0;

  try
      //DBGrid 의 캡션을 워크시트의 첫행에 출력한다.
    for Col := 0 to ADataSet.Fields.Count - 1 do
    begin
      if AGrid.Columns[Col].Visible then //DBGrid 의 컬럼이 Visible 일 때만 진행한다.
      begin
        Cell := Sheet.WriteText(Row, VisCol, AGrid.Columns[Col].Title.Caption);
        Sheet.WriteBackgroundColor(cell, clMoneyGreen); //첫 행의 배경색  
        VisCol := VisCol + 1;
      end;
    end;

    Inc(Row); //워크시트를 두번재 행으로 이동
    ADataSet.First; //데이터세트의 첫행으로 이동

    while not ADataSet.EOF do  //마지막 레코드까지 계속 진행한다.
    begin
      VisCol := 0;
      for Col := 0 to AGrid.Columns.Count - 1 do
      begin
        if AGrid.Columns[Col].Visible then //DBGrid 의 컬럼이 visible 일때만 진행한다.
        begin
          Field := AGrid.Columns[Col].Field; //DBGrid 의field 를 넣고 type 을 결정한다.

          if Field.DataType in [ftInteger, ftWord, ftSmallint, ftAutoinc, ftLargeInt] then
            Sheet.WriteNumber(Row, VisCol, ADataSet.Fields[Col].AsInteger)
          else if Field.DataType in [ftBCD, ftFloat, ftFMTBcd] then
            Sheet.WriteNumber(Row, VisCol, ADataSet.Fields[Col].AsFloat)
          else if Field.DataType in [ftCurrency] then
            Sheet.WriteCurrency(Row, VisCol, ADataSet.Fields[Col].AsFloat)
          else if Field.DataType in [ftString, ftFixedChar] then
            Sheet.WriteText(Row, VisCol, ADataSet.Fields[Col].AsString)
          else if Field.DataType in [ftWideMemo, ftWideString, ftFixedWideChar] then
            Sheet.WriteText(Row, VisCol, UTF8Encode(ADataSet.Fields[Col].AsWideString))
          else if Field.DataType in [ftMemo, ftFmtMemo, ftWideMemo] then
            Sheet.WriteText(Row, VisCol, ADataSet.Fields[Col].AsString)
          else if Field.DataType = ftBoolean then
            Sheet.WriteBoolValue(Row, VisCol, ADataSet.Fields[Col].AsBoolean)
          else
            Sheet.WriteText(Row, VisCol, ADataSet.Fields[Col].AsString);
          VisCol := VisCol + 1; //DBGrid 의 컬럼이 visible 일때만 워크시트의 오른쪽으로 증가시킨다.
        end;
      end;

      Inc(Row);
      ADataSet.Next;
    end;

    Book.WriteToFile(AFileName, sfOOXML, True);
    QuestionDlg('엑셀 내보내기', '엑셀파일 ' + AFileName +
        ' 가 만들어졌습니다.', mtCustom, [mrYes, '확인'], '');

  finally
    Book.Free;
  end;
end;

최종 결과물은 다음과 같다.

[ 엑셀 문서로 출력한 결과 ]

라자루스(Lazarus) 프로젝트 Hi-DPI 설정하기

appleii — Mon, 16 Aug 2021 17:51:22 +0900

라자루스는 Hi-DPI (High DPI) 를 지원한다. 그 이야기는 화면을 확대해도 글자가 흐릿하지 않는다는 뜻이다. 하지만 라자루스에서 Hi-DPI 를 지원하기 이전에 작성된 프로젝트의 경우는 HiDPI 설정이 되어 있지 않은 경우가 많다. 이경우 수동으로 설정하여 다시 저장해야 한다.

- Use LCL scaling (Hi-DPI) 를 체크
- Use manifest resource 를 체크 한 후에 DPI awareness 를 on (True) 로 선택한다.

2개를 체크한 후에 메인메뉴에서 Project -> Close Project 하여 프로젝트를 닫아주고 다시 Open Project 로 다시 열어준다. F9를 눌러서 다시 실행한다. 안된다면 메인메뉴에서 Run -> Clean up and Build 하여 다시 빌드한 후에 실행한다.

잉크스케이프(Inkscape) Theme 폰트 키우기

appleii — Sat, 14 Aug 2021 10:02:37 +0900

벡터 드로잉 툴인 잉크스케이프가 1.1 로 버전업 되면서 안정성이 대단히 좋아졌다. 하지만 여전히 불만이 있는데, 테마의 폰트 크기가 너무 작다는 것이다. 테마를 수정하여 폰트 크기를 키우는 법을 알아보자.

64비트로 설치를 했다면 경로는
C:\Program Files\Inkscape\share\inkscape\ui\style.css

이 된다. style.css 를 수정해야 한다. 아래와 같이 수정한다. font-size 를 20px 또는 적당한 값으로 수정한다. 폰트 종류를 바꾸고 싶다면 font-family 에서 적당한 것으로 수정한다.

*{
    font-feature-settings: "tnum=1";
    font-size: 20px;
    font-family: sans-serif;
}

#start-screen-window notebook > *:nth-child(2) label{
    font-size:22px;
}

*{ } 사이에 있는 font-size 는 메인 프로그램의 폰트 크기에 영향을 준다. #start-screen-window 의 font-size 는 시작할 때 나오는 창의 폰트 크기에 영향을 준다. 레이아웃이 약간 안 맞지만 큰 문제는 안된다.

툴팁의 배경이 반투명이어서 마음에 들지 않는다면 아예 검은색으로 바꾸는 방법도 있다.

tooltip{
background-color: black;
border-color: coral;
}

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (4) 엑셀파일 출력 I

appleii — Wed, 11 Aug 2021 11:00:31 +0900

SQLite 로 관리한 데이터를 애플리케이션에서 가공하여 엑셀로 출력하고 싶다. 라자루스에서는 엑셀과 비슷한 애플리케이션을 만들 수 있는 컴포넌트가 있다. 이것을 이용하여 데이터를 엑셀로 출력해 본다.

8. 컴포넌트 설치

엑셀 파일 관리를 위해서 새로운 컴포넌트를 설치해야 한다. 설치할 컴포넌트는 FPSpreadSheet 컴포넌트이다. 컴포넌트 설치 방법은 온라인으로 하는 것이 제일 편하다. 메인메뉴에서 Package -> Online Package Manager 를 선택한다.

검색창에 fpspreadsheet 를 치고 체크박스에 체크를 한 뒤 Install 을 클릭한다.

설치뒤에는 라자루스를 리빌드하게 된다. 리빌드가 끝나면 라자루스가 재실행된다. 컴포넌트 팔렛트에 FPSpreadsheet 탭이 생긴것을 알 수 있다.

9. 엑셀 파일로 출력

uses 에 FPSexport 를 추가해준다. 이 상태에서 F9키를 눌러서 실행하려 하면 에러가 발생한다. 필요한 패키지를 프로젝트에 포함시키지 않았기 때문이다. Project Inspector 에서 Required Packages 에 커서를 위치시키고 우클릭을 하면 Add 가 팝업된다. Add 를 하면 다음과 같은 창이 뜬다.

검색창에 fps 를 입력하면 관련 패키지 목록이 나타난다. 필요한 패키지는 laz_fpspreadsheetexport_visual 이다. 선택한다. Project Inspector 에 Required Packages 를 보면 laz_fpspreadsheetexport_visual 이 추가된 것을 알 수 있다.

F12 키를 눌러서 폼 디자인 화면으로 넘어간다. 버튼을 폼 위에 올리고 Object Inspector 에서 Name Property 를 'btnXLExport' 라고 수정한다. Caption 은 '엑셀 내보내기' 로 수정한다.

버튼을 더블 클릭하여 이벤트 핸들러 작성 화면으로 넘어간다.

procedure TMainForm.btnXLExportClick(Sender: TObject); 
var 
  Exp: TFPSExport; 
  ExpSettings: TFPSExportFormatSettings; 
begin 
  DataSource1.DataSet.First; 
  Exp := TFPSExport.Create(nil); 
  ExpSettings := TFPSExportFormatSettings.Create(true); 
  try 
    ExpSettings.ExportFormat := efXLSX; // 엑셀 2007 이상에서 사용하는 포맷 
    ExpSettings.HeaderRow := true; // 필드 이름 포함 
    Exp.FormatSettings := ExpSettings; 
    Exp.Dataset := DataSource1.DataSet; //데이터세트를 DataSource1 의 DataSet 으로 지정 
    Exp.FileName := 'pass_export.xlsx'; 
    Exp.Execute; 
    QuestionDlg('엑셀 내보내기', '엑셀파일 ' + Exp.FileName  + ' 가 만들어졌습니다.', mtCustom, [mrYes, '확인'], '') ; 
  finally 
    Exp.Free; 
    ExpSettings.Free; 
  end; 
end;

F9 키를 눌러서 실행시키고 '엑셀 내보내기' 버튼을 클릭하면 'pass_export.xlsx 가 만들어졌습니다.' 다이얼로그 박스가 뜬다. pass_export.xlsx 를 엑셀에서 열면 다음과 같이 출력된다. ExpSettings.HeaderRow := true; 로 설정되어 있어서 제일 위에 필드 이름이 포함되어 출력되었다.

이제 SQLite 를 통해서 데이터베이스로 비밀번호를 관리하고 엑셀로 출력할 수 있는 비밀번호 관리 애플리케이션이 완성되었다.

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (3) 기타기능

appleii — Wed, 11 Aug 2021 11:00:23 +0900

5. 한글, 영문 입력 모드 바꾸기

웹사이트 이름을 한글로 입력하게 되어 있는 Edit 컨트롤이면 별도의 한/영 키 전환 없이 자동으로 한글입력모드가 되면 편하다. 영문 입력만 해야 한다면 자동으로 영문 입력모드로 전환되면 된다.

하지만 라자루스는 델파이와 다르게 입력기를 제어하기가 어렵다. 입력기가 운영체제와 밀접하게 연관되어 있어서 , 크로스 플랫폼을 지향하는 라자루스와는 방향이 맞지 않기 때문이다.

그래서 입력 컨트롤의 입력기 모드를 제어하는 ImeMode Property 가 구현되어 있지 않다. 소스를 보면 해당 부분은 주석 처리가 되어 있다. 하지만 다행스럽게도 입력기를 제어하기 위한 인터페이스는 파스칼로 구현되어 있다. imm.pas 에 인터페이스가 있기 때문에 기능을 사용하고 싶으면 uses 에 imm 을 추가하면 된다. 그렇다면 라자루스에서 어떻게 구현할 것인가가 문제인데, 그냥 단순하게 입력 컨트롤이 포커스를 받으면 입력모드를 바꾸는 것으로 구현했다. 입력 컨트롤이 포커스를 잃으면 다시 원래대로 돌아가면 된다.

Edit1 컨트롤은 한글을 우선 입력받는 컨트롤이고 Edit2 는 영문을 우선 입력받는 컨트롤이라고 가정한다. Edit1 이 포커스를 받으면 OnEnter 이벤트 핸들러가 동작한다. 이때 입력기를 한글 입력모드로 바꾸고 , 포커스를 잃어버리는 OnExit 에서 원래의 입력모드로 전환하면 된다.

procedure TForm1.Edit1Enter(Sender: TObject); 
begin 
  ImmSetConversionStatus(ImmGetContext(Edit1.Handle), IME_CMODE_HANGEUL, IME_SMODE_NONE); 
end; 

procedure TForm1.Edit1Exit(Sender: TObject); 
begin 
  ImmSetConversionStatus(ImmGetContext(Edit1.Handle), IME_CMODE_ALPHANUMERIC, IME_SMODE_NONE); 
end;

6. 클립보드

uses 에 Clipbrd 를 추가한다. Clipboard.AsText 로 클립보드에 복사한다. [복사] 버튼을 누르면 클립보드에 복사하게 되므로 아이디 나 비밀번호 입력시에 Ctrl+V 로 붙여넣기 하면 된다.

procedure TMainForm.btnCopyPWClick(Sender: TObject);
begin
  Clipboard.AsText := EditPW.Text;
end;

procedure TMainForm.btnCopyIDClick(Sender: TObject);
begin
  Clipboard.AsText := EditID.Text;
end;

7. 인터넷 주소 연결

OpenURL 을 사용한다. uses 에 LCLIntf 를 추가한다. 웹사이트 입력란에 아무것도 없으면 한글 이름으로 구글 검색을 하도록 만든다. 웹사이트 주소를 제대로 입력했다면 OpenURL 에서 True 반환하여 Exit 한다. 아니라면 다음 문장을 실행하는데 'http://' 를 이름 앞에 붙이는 것이다. 실행해 본 결과 https 가 가능하도록 처리한 웹사이트들은 http 로 연결을 시도하면 대부분 자동으로 https 로 연결한다.

procedure TMainForm.btnOpenURLClick(Sender: TObject);
begin
  if EditWebSite.Text = '' then
  begin
    OpenURL('www.google.com/search?q=' + EditNameKorean.Text);
    Exit;
  end;
  if OpenURL(EditWebSite.Text) then Exit;
  if OpenURL('http://' + EditWebSite.Text) then Exit;
end;

4편에서는 엑셀파일로 출력하는 것을 구현해 본다.

4편에서 계속
https://appleii.tistory.com/177

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (2) 데이터베이스

appleii — Wed, 11 Aug 2021 11:00:15 +0900

3. SQLite

데이터베이스는 SQLite 를 사용한다. 한개의 dll 파일만 있으면 되고 별도의 설치 과정이 필요 없으므로 간단한 응용 프로그램을 만들기에 적합하다. SQLite 는 다음 사이트에서 다운로드 받는다.
https://www.sqlite.org/download.html

Precompiled Binaries for Windows 중에서 32비트 또는 64비트 환경에 맞는 것으로 다운로드 받는다. 예를 들어 자신이 64비트 윈도우를 사용하고 있다면 sqlite-dll-win64-x64-3360000.zip 을 다운로드 받는다. 압축을 풀면 sqlite3.dll 이 나온다. 이 라이브러리 파일 한개로 데이터베이스 관리를 할 수 있는 것이다. 별도의 경로를 지정하지 않았다면 sqlite3.dll 이 실행파일과 같은 폴더 내에 있어야 한다.

라자루스에서는 SQLite 를 사용하기 위한 컴포넌트를 제공하고 있다. 컴포넌트 팔렛트에서 SQLdb 탭을 선택한 후 TSQLite3Connection 컴포넌트를 폼 위에 올려 놓는다.

그리고 데이터베이스 관리를 위해서 TSQLQuery, TSQLTransation, Data Access 탭에서 TDataSource 를 선택하여 폼에 올려 놓는다. TSQLite3Connection 을 이용하여 SQLite 와 연결된다. 이 데이터를 가져와서 DBGrid 에서 가공하기 편하도록 변환시켜야 한다. DataSource 에서 이 역할을 한다. 데이터베이스에 SQL 명령문을 전달하기 위해서 SQLQuery 를 이용한다. 기본적인 원리는 SQLConnection 을 이용하여 SQLite 에 접근 -> 데이터베이스 생성 -> 자료입력 -> DataSource 로 데이터베이스 검색 결과 출력 -> DBGrid 화면으로 출력

각 컴포넌트의 Property 는 다음과 같이 지정한다.

(1) DataSource1 의  (Property)  Database : SQLite3Connection1
(2) SQLQuery1 의 (Property) Database  :  SQLite3Connection1  ,
Transation : SQLTransaction1
(3) SQLTransaction1 의 (Property) Database  : SQLite3Connection1
(4) SQLite3Connection1 의 (Property) Transaction : SQLTransaction1
(5) DBGrid1 의 (Property) DataSource : DataSource1

FormShow 또는 FormCreate 이벤트 핸들러에 다음 문장을 삽입한다. SQLite 라이브러리 이름을 지정한다.

SQLiteLibraryName := 'sqlite3.dll';
SQLite3Connection1.DatabaseName := 'pass.db'; //이름을 정해주면 create 에서 자동 생성

4. 데이터베이스(생성, 추가, 삭제, 수정, 검색, 백업)

비밀번호 관리를 위해서는 테이블이 필요하다. 테이블 내에는 항목을 나타내는 컬럼이 있다. 비밀번호는 웹사이트에 로그인하기 위해서 사용하는 것이 대부분이므로 웹사이트 주소를 나타내는 컬럼이 필요하다. 그외에 필요한 컬럼은

[0] Primary Key - PK : 각각의 레코드를 구별하는 유일한 키값
[1] 이름 (한글) - NameKorean : 필요한 웹사이트의 이름 한글로 표시
[2] 이름 (영문) - NameEnglish : 한글이름을 잘못 알고 있거나 영문으로만 알고 있을 때 사용
[3] 웹사이트 - WebSite : 웹사이트 주소를 표시
[4] 아이디 - ID : 웹사이트 또는 다른 프로그램의 로그인 아이디
[5] 비밀번호 - PW : 로그인 비밀번호
[6] 기타메모 - Memo : 로그인 실패시에 웹사이트에서 확인하는 질문에 대한 대답 또는 주의사항

DBGrid 를 더블클릭하여 에디터를 실행시키고 Add 버튼을 눌러서 컬럼을 추가해 나간다. DBGrid 와 데이터베이스의 컬럼명은 정확히 같아야 한다.

화면에 표시되는 DBGrid1 의 컬럼 이름을 바꾸고 싶다면 Object Inspector 에서 각각의 컬럼을 선택하여 Title 의 Caption Property 를 바꾸면 된다. Title 왼쪽의 [>] 를 누르면 Title 에 부속된 Property 가 확장된다.

(1) 생성 (CREATE)
CREATE TABLE 을 사용한다. 같은 폴더내에 SQLite3 가 없으면 에러가 발생한다. pass.db 가 없으면 새로 만들어서 테이블을 생성한다. SQL 문장을 입력시에 SQLQuery1.SQL.Add 로 추가하고 SQLQuery1.ExecSQL; 로 실행한다. 트랜잭션은 SQLTransaction1.Commit; 으로 마무리하는 것을 잊지 말아야 한다.

procedure TMainForm.CreateDB(); 
var 
  NewFile: boolean; 
begin 
  SQLite3Connection1.Close(); //항상 닫았는지 확인 
  SQLQuery1.SQL.Clear; 

  try 
    NewFile := not FileExists(SQLite3Connection1.DatabaseName); 
    //이미 데이터베이스 있는가 확인 

    if NewFile then 
    begin 
      try 
        SQLite3Connection1.Open; 
        SQLTransaction1.Active := True; 

        SQLQuery1.SQL.Add('CREATE TABLE "DATA"('); 
        SQLQuery1.SQL.Add(' "PK" INTEGER NOT NULL PRIMARY KEY AUTOINCREMENT,'); 
        SQLQuery1.SQL.Add(' "NameKorean" VARCHAR(20) NOT NULL,'); 
        SQLQuery1.SQL.Add(' "NameEnglish" VARCHAR(20) ,'); 
        SQLQuery1.SQL.Add(' "WebSite" VARCHAR(30) ,'); 
        SQLQuery1.SQL.Add(' "ID" VARCHAR(20) NOT NULL,'); 
        SQLQuery1.SQL.Add(' "PW" VARCHAR(20) NOT NULL,'); 
        SQLQuery1.SQL.Add(' "Memo" VARCHAR(300) );'); 

        SQLQuery1.SQL.Add('CREATE UNIQUE INDEX "Data_id_idx" ON "DATA"( "PK" );'); 

        SQLQuery1.ExecSQL; 
        SQLTransaction1.Commit;   //꼭 넣을것 잊지말고 

        QuestionDlg('DB 생성', '데이터베이스 ' + SQLite3Connection1.DatabaseName + ' 가 만들어졌습니다.', mtCustom, [mrYes, '확인'], '') ; 
        btnClearClick(nil); 
      except 
        ShowMessage('데이터베이스를 만들 수 없습니다.'); 
      end; 
    end; 
  except 
    ShowMessage('파일이 존재하지 않습니다.'); 
  end; 
end;

(2) 추가 (INSERT)
아무것도 입력되어 있지 않으면 경고창을 보여주고 재입력을 요구한다. SQLQuery1 을 이용하여 SQL 문장을 전달한다. ':' 로 파라메터를 대신 전달할 수 있다. ':NameKorean' 으로 SQL 문장에 파라메터로 지정하면 이 파라메터에 다른 입력 컨트롤의 값을 대입할 수 있다. 파스칼의 대입문 ':=' 와 모양이 비슷하므로 착각하기 쉽다. '= :' 는 ':=' 와 다르다는 점을 기억하자.

procedure TMainForm.btnInsertClick(Sender: TObject); 
begin 
  if (EditNameKorean.Text = '') or (EditID.Text = '') or (EditPW.Text = '') then 
  begin 
    QuestionDlg('입력오류', '필수항목을 꼭 입력해 주세요.', mtCustom, [mrYes, '확인'], '') ; 
    btnClearClick(nil); 
    Exit; 
  end; 

  SQLite3Connection1.Close; 
  SQLQuery1.SQL.Clear; 

  try 
    SQLite3Connection1.Open; 
    SQLTransaction1.Active := True; 

    SQLQuery1.SQL.Add('INSERT INTO DATA (NameKorean, NameEnglish, WebSite, ID, PW, Memo)'); 
    SQLQuery1.SQL.Add(' VALUES (:NameKorean, :NameEnglish, :WebSite, :ID, :PW, :Memo)'); 

    SQLQuery1.Params.ParamByName('NameKorean').AsString := EditNameKorean.Text; 
    SQLQuery1.Params.ParamByName('NameEnglish').AsString := EditNameEnglish.Text; 
    SQLQuery1.Params.ParamByName('WebSite').AsString := EditWebSite.Text; 
    SQLQuery1.Params.ParamByName('ID').AsString := EditID.Text; 
    SQLQuery1.Params.ParamByName('PW').AsString := EditPW.Text; 
    SQLQuery1.Params.ParamByName('Memo').AsString := Memo.Lines.Text; 

    SQLQuery1.ExecSQL; 
    SQLTransaction1.Commit; 

    btnClearClick(nil); 
    UpdateGridAll('Last'); 
  except 
    ShowMessage('자료를 추가하지 못했습니다.'); 
  end; 
end;

(3) 삭제 (DELETE)

삭제를 위해서 현재 Row 값을 저장하는 Currow 을 멤버 변수로 지정한다. DataSource1 의 DataChange 이벤트 핸들러에 Currow := SQLQuery1.FieldByName('PK').Value; 를 추가하여 현재의 Row 값을 저장한다.

procedure TMainForm.btnDeleteClick(Sender: TObject);
begin
  if QuestionDlg('레코드 삭제', '정말 삭제하시겠습니까?', mtCustom,
  [mrYes, '예', mrNo, '아니요'], '') = mrNo then Exit;

  SQLite3Connection1.Close; //Close, Clear 시작전 꼭 확인
  SQLQuery1.SQL.Clear;      //sqlquery1.sql.clear 를 주의할것  sqlquery1.clear 가 아니다.

  try
    SQLite3Connection1.Open;
    SQLTransaction1.Active := True;

    SQLQuery1.SQL.Add('DELETE FROM DATA WHERE PK = :Currow'); //현재 위치의 레코드 삭제

    SQLQuery1.Params.ParamByName('Currow').Value := Currow;

    SQLQuery1.ExecSQL;
    SQLTransaction1.Commit;

    btnClearClick(nil);
    UpdateGridAll('First'); //삭제 후에는 처음 레코드로 이동한다.
  except
    ShowMessage('삭제 실패했습니다.');
  end;
end;

(4) 수정 (UPDATE)
현재의 레코드를 기록한 후에 UPDATE 명령어로 수정해준다.

procedure TMainForm.btnUpdateRowClick(Sender: TObject);
begin
  if QuestionDlg('레코드 수정', '정말 수정하시겠습니까?', mtCustom,
  [mrYes, '예', mrNo, '아니요'], '') = mrNo then Exit;

  SQLite3Connection1.Close();
  SQLQuery1.SQL.Clear;

  try
    SQLite3Connection1.Open;
    SQLTransaction1.Active := True;

    SQLQuery1.SQL.Add('UPDATE DATA SET NameKorean = :NameKorean,');
    SQLQuery1.SQL.Add('NameEnglish = :NameEnglish, ');
    SQLQuery1.SQL.Add('WebSite = :WebSite,');
    SQLQuery1.SQL.Add('ID = :ID, ');
    SQLQuery1.SQL.Add('PW = :PW, ');
    SQLQuery1.SQL.Add('Memo = :Memo ');
    SQLQuery1.SQL.Add(' WHERE PK = :Currow');

    SQLQuery1.Params.ParamByName('NameKorean').AsString := EditNameKorean.Text;
    SQLQuery1.Params.ParamByName('NameEnglish').AsString := EditNameEnglish.Text;
    SQLQuery1.Params.ParamByName('WebSite').AsString := EditWebSite.Text;
    SQLQuery1.Params.ParamByName('ID').AsString := EditID.Text;
    SQLQuery1.Params.ParamByName('PW').AsString := EditPW.Text;
    SQLQuery1.Params.ParamByName('Memo').AsString := Memo.Lines.Text;
    SQLQuery1.Params.ParamByName('Currow').Value := Currow;

    SQLQuery1.ExecSQL;
    SQLTransaction1.Commit;

    btnClearClick(nil);
    UpdateGridAll('Current');
  except
    ShowMessage('수정오류');
  end;
end;

(5) 검색 (SEARCH)
폼 화면 위에 ActionList 를 올려 놓는다. 단축키를 사용할 수 있게 해준다. ActionList 를 더블클릭하면 에디터가 팝업된다.

[+] 를 클릭하여 Action1, Action2 를 만들고 Object Inspector 에서 Action1 을 선택한다. Properties 탭에서 Name 은 'Search Action' 으로 변경하고 ShortCut 은 'Ctrl+F' 로 지정한다. Events 탭에서 OnExecute 이벤트를 더블 클릭하여 이벤트 핸들러를 작성한다. Ctrl+F 를 누르면 자동으로 검색에디트에 포커스가 가서 검색할 수 있게 된다.

procedure TMainForm.SearchActionExecute(Sender: TObject);
begin
EditSearch.SetFocus;
end;

검색에디트에서는 한글이름 또는 영문이름 일부라도 입력되면 검색되도록 하였다.

procedure TMainForm.btnSearchClick(Sender: TObject);
begin
  if (EditSearch.Text = '') then Exit;

  SQLite3Connection1.Close();
  SQLQuery1.SQL.Clear;

  try
    SQLite3Connection1.Open;

    SQLQuery1.SQL.Add('SELECT * FROM DATA WHERE ');
    SQLQuery1.SQL.Add('(NameKorean LIKE :NameKorean) OR ');
    SQLQuery1.SQL.Add('(NameEnglish LIKE :NameEnglish)');

    SQLQuery1.Params.ParamByName('NameKorean').Value := '%' + EditSearch.Text + '%';
    SQLQuery1.Params.ParamByName('NameEnglish').Value := '%' + EditSearch.Text + '%';

    SQLQuery1.Open;

    DataSource1.DataSet := SQLQuery1;
    DBGrid1.DataSource := DataSource1;
    DBGrid1.AutoFillColumns := True;
  except
    ShowMessage('검색할 수 없습니다.');
  end;
end;

(6) 백업 (BACKUP)
비밀번호는 수정이 잘못 일어나면 곤란하므로 자주 백업을 해주어야 한다. 수정한 날자를 파일명에 삽입해서 이전에 기록한 비밀번호를 찾아갈 수 있도록 하였다.
만약 특정 레코드를 실수로 삭제한후에 나중에서야 실수임을 발견했다면 백업한 DB 에서 단서를 찾을 수 있을 것이다.
프리파스칼에서 기본으로 제공하는 기능이므로 uses 에 Sqlite3backup 를 추가한다.

procedure TMainForm.BackupSQL(Conn: TSQLite3Connection; FileName: String);
var
  f: String;
  BK: TSQLite3Backup;
begin
  f := ChangeFileEXT(FileName, '') + ' [Backup ' +
    FormatDateTime('yyyy.mm.dd hh-nn-ss', Now) + '].db';
  BK := TSQLite3Backup.Create;
  BK.Backup(Conn, f);
  BK.Free;
  QuestionDlg('DB 백업', 'DB 가 ' + f + '  로 백업되었습니다.', mtCustom, [mrYes, '확인'], '');
end;

3편에서는 한글입력이 필요할때는 자동으로 입력모드를 한글로 바꾸는 방법과, 클립보드 복사, 인터넷 브라우저를 실행시켜 특정 웹사이트로 이동하는 방법을 구현해 본다.

3편에서 계속
https://appleii.tistory.com/176

라자루스로 만들어 보는 비밀번호 관리 프로그램 [뭐였더라] (1) 폼 디자인

appleii — Wed, 11 Aug 2021 11:00:05 +0900

파스칼 언어로 작성하는 GUI 개발 도구인 라자루스로 간단한 비밀번호 관리 프로그램을 만들어 보자.

비밀번호를 종이에 적어서 관리할 수도 있고 엑셀로 관리할 수도 있지만 종이는 분실되기 쉽고 엑셀은 오피스가 설치된 PC 에서만 사용이 가능하다. 간단한 입력화면을 가진 전용 프로그램을 만드는 것이 제일 좋은 해결 방법이다. GUI 개발도구는 여러가지가 있지만 오브젝트 파스칼 언어로 작성하는 라자루스가 제일 편하다. 데이터베이스는 SQLite3 를 사용한다. whatwas.zip 에는 실행파일과 SQLite3 가 있다. whatwas_source 에는 소스코드가 있다. whatwas.exe 를 실행시키면 경고창이 뜨면서 다운로드 받은 파일임을 알린다. [추가정보]를 누른 후 [실행] 을 누른다. whatwas_source.zip 을 다운로드 받은 후에 압축을 풀어서 whatwas.lpi 를 더블 클릭하면 프로젝트가 열린다.

1. 라자루스 설치

라자루스 IDE 는 다음 사이트에서 다운로드 받아 설치한다. [DownLoad Now] 버튼을 누르면 다운로드 된다.
https://www.lazarus-ide.org/

IDE 의 폰트 문제는 다음을 참고하여 수정하고 라자루스 IDE 를 다시 빌드시키면 된다.
https://appleii.tistory.com/172

SDI 방식이므로 툴들을 화면에 적당히 배치시켜야 한다. 배치가 끝났으면 Desktop 을 저장한다.

메인 메뉴에서 Project -> New Project -> Application 순서대로 선택한다.

새로운 폼이 화면에 뜬다. 이제 폼위에 컨트롤을 배치해 본다. 컴포넌트 팔렛트에서 Standard 탭을 선택한 후에 Button을 선택한 후 Form위에 올려 놓는다.

버튼을 더블 클릭하면 클릭 이벤트 핸들러가 만들어 진다. 원하는 동작을 채워 넣으면 된다. Close; 를 입력하고

procedure TForm1.Button1Click(Sender: TObject);
begin
Close;
end;

F9키를 눌러서 실행한다. 이 버튼을 누르면 프로그램이 종료된다. 이런식으로 이벤트 핸들러를 채워 나가면서 개발한다.

2. 폼 디자인

기본적인 디자인은 입력폼과 DB 내용을 표시하는 DBGrid , 그리고 제어하는 버튼들로 구성된다.

비밀번호를 관리하기 위해서는 데이터베이스에 한글이름, 영문이름, 웹사이트, 비밀번호가 저장되어야 한다. 저장된 데이터를 불러와서 화면에 출력하면 되는 것이다. 다음 컨트롤이 필요하다.

(1) 데이터를 입력받기 위한 Edit, Memo
(2) 입력해야 하는 데이터를 설명하는 Label
(3) 관련되는 컨트롤을 모아서 보여주는 GroupBox
(4) 원하는 동작을 하기 위한 Button
(5) 데이터베이스에서 데이터를 읽어 화면에 표시하는 DBGrid

위의 컨트롤들은 폼 화면에 표시되는 컴포넌트(Visual Component) 이다. 폼에 직접적으로 나타나지는 않지만 폼 위에 올릴 수 있는 컴포넌트는 보이지 않는 컴포넌트(Non-Visaul Component)이다. 데이터베이스를 읽고 쓰기 위해서는 관련 컴포넌트를 폼위에 올려 놓아야 한다.

실행시에는 보이지 않지만, 디자인시에 값을 바꿀 수 있다. 배치가 끝났으면 Unit1.pas 대신에 frmMain.pas 로 저장한다. 프로젝트 이름은 whatwas.lpi 로 저장한다. whatwas.lpr 도 같이 생성된다. lpr 은 실질적인 메인 진입 코드이다. lpi 에는 프로젝트 관리에 필요한 파일의 위치, 리소스 등이 저장된다. 폼이 새로 만들어지면 폼의 데이터를 저장하는 파일이 생성된다. 확장자는 lfm 이다. frmMain.pas 는 폼의 논리적인 작동방법이 나타나 있고, frmMain.lfm 에는 폼에 올려져 있는 컨트롤의 위치 등이 저장되어 있다. frmMain.pas 에서 F12 키를 누르면 폼 화면으로 전환되어 폼 디자인을 할 수 있고, 폼 디자인 상태에서 F12 키를 누르면 frmMain.pas 로 전환된다. 만들어지는 파일은 다음과 같다.

whatwas.lpi 프로젝트
whatwas.lpr 메인 진입코드
whatwas.lps 세션
whatwas.ico 아이콘
whatwas.res 리소스
frmMain.pas 폼의 논리구조를 구현하는 코드
frmMain.lfm 폼위에 오려진 컨트롤 크기 , 위치 등의 데이터

폼의 크기를 조절하지 못하도록 하기 위해서 Object Inspector 에서 Properties 탭을 선택한 후 BorderStyle 을 bsSingle 로 지정한다.

Object Pascal 언어는 Property 를 통해서 값을 넣고 빼는 작업을 할 수 있다. 라자루스 에서는 Property 들을 Object Inspector에서 관리할 수 있도록 하고 있다. Form 의 Name 을 MainForm 으로 바꾸면 Object Inspector 의 트리뷰에서도 이름이 바뀐다. 또한 소스코드상에서의 이름도 자동으로 바뀐다.

그럼 화면에 표시되는 내용을 바꾸려면 어떻게 해야 할까. 화면에 표시되는 내용은 Caption 에서 바꿀 수 있다. Button 의 Name 을 btnInsert 로 바꾸고 Caption 을 추가 로 바꾸면 소스코드상에서의 버튼의 이름은 btnInsert 로 바뀌고 화면에 표시되는 버튼위의 글자는 '추가'로 바뀌는 것이다. 이런식으로 폼위에 위치한 컨트롤들을 하나하나 바꾸어 나간다.

2편에서는 SQLite 와 데이터베이스 처리를 구현해 본다.

2 편에서 계속
https://appleii.tistory.com/175

파스칼 언어로 작성하는 GUI 개발 도구인 라자루스로 간단한 비밀번호 관리 프로그램을 만들어 보자.

김프(GIMP) 2.10.32 다크테마(Dark Theme) 수정

appleii — Sat, 7 Aug 2021 15:32:39 +0900

김프(GIMP) 는 포토샵 대체용으로 많이 쓰고 있지만 인터페이스가 좋지는 못하다. 과거에는 SDI 방식이어서 더 그랬던 것 같다. 몇 번이나 도전해 봤지만 윈도우에서는 GTK 가 너무 불안해서 10분도 못 버티고 강제종료되는 경우가 많아서 더 힘들었던 것 같다. 최근에 다시 도전해 본 GIMP 는 엄청난 발전이 있었다. 안정성도 높아졌고 이제는 인터페이스도 도킹이 가능한 방식으로 바뀌었다. 하지만 여전히 문제가 있는데 바로 테마 기능이다. 다크 테마가 아무리 적응하려 해도 안되는 것이다. 색상별 구분이 잘 안되어서 무엇을 선택하였는지 알 수 없게 만들었기 때문이다.

다행히도, 김프는 gtkrc 를 수정하면 제한적이지만 원하는 대로 바꿀수가 있다.

시인성을 최대한 높이고 글자 크기를 키우는 방향으로 테마를 수정해 보았다.

gtkrc

0.04MB

64비트 버전을 설치했다면 경로는 C:\Program Files\GIMP 2\share\gimp\2.0\themes\Dark\gtkrc 가 된다.

원래의 gtkrc 는 이름을 gtkrc_original 등으로 변경한후 gtkrc 를 다운로드 받아서 필요한 폴더에 덮어쓰기 하면 된다.

수정에 참고할 만한 사항들 몇가지를 나열해 본다.

1. 폰트 크기 바꾸기 #font_name 에서 주석처리된 #을 지우고 사이즈를 변경한다. Sans 는 폰트이름, 12 는 폰트사이즈이다.
style "gimp-dark-default-style"
{
  font_name = "Sans 12"

2. 도킹 가능한 다이얼로그 외곽선 크기조절
GimpDockable::content-border = 5

3. 다이얼로그 외곽선 크기조절
GtkDialog::content-area-border = 5

4. 마우스 호버 색상 (체크박스, 폴딩 메뉴)
color["clr7"]  = "#196994"

5. 메인메뉴 글자색
style "gimp-dark-menu-item"  에서
fg[PRELIGHT] = "#ff9500"

6. 값을 조절하는 슬라이더 색 (스케일 위젯?)
bg[SELECTED] = @clr7

7. 버튼 호버링시에 색상 변화
style "gimp-dark-button-style"  에서
fg[PRELIGHT] = "#ff9500" #버튼 글자색
bg[PRELIGHT] = "#196994" #버튼 배경색

라자루스 IDE (Lazarus IDE) default 폰트 문제 해결법

appleii — Wed, 28 Jul 2021 20:20:32 +0900

라자루스 IDE (Lazarus IDE) 에서 폰트이름의 기본값은 'default' 이다. DefFontData 에 그렇게 정의되어 있다.

DefFontData: TFontData = (
    Handle: 0;
    Height: 0;
    Pitch: fpDefault;
    Style: [];
    Charset: DEFAULT_CHARSET;
    Quality: fqDefault;
    Name: 'default';
    Orientation: 0;
    );

폰트의 기본값을 초기에 정하지 않고 상황에 따라서 시스템의 폰트를 다르게 하여 표시하겠다는 의도이다. 실제 컨트롤에 폰트를 표시하려면 시스템의 폰트를 알아내야 한다. 문제는 현재 라자루스 IDE 버전(2.0.12)에서는 시스템폰트이름을 제대로 읽어내지 못한다. 윈도우10 에서의 시스템폰트는 '맑은 고딕' 이지만 자꾸 '굴림' 폰트를 사용한다. 폰트가 너무 얇아서 가독성이 떨어지는 것이 문제이다. 단순히 라자루스 IDE 폰트만 문제가 되는 것이 아니라, 폼 위에 컨트롤을 올리는 순간 폰트가 '굴림' 폰트가 되는 것이 문제다.

해당 기능을 구현한 코드를 수정한 후 라자루스 IDE 를 다시 빌드하면 된다.

해당코드는 (설치 드라이브가 C드라이브일경우) C:\lazarus\lcl\interfaces\win32\win32winapi.inc 에 TWin32WidgetSet.CreateFontIndirect 로 구현되어 있다. 해당 함수를 다음과 같이 수정하면 된다.

function TWin32WidgetSet.CreateFontIndirect(const LogFont: TLogFont): HFONT;
var
  TempLogFontW: TLogFontW;
  TempLogFont: TLogFontA absolute TempLogFontW;
  FontName: String;
begin
  FontName := LogFont.lfFaceName;

  TempLogFont := LogFont;
  if IsFontNameDefault(FontName) then
  begin
    TempLogFontW.lfFaceName := Screen.SystemFont.Name; //
    //TempLogFontW.lfFaceName := UTF8ToUTF16(FMetrics.lfMessageFont.lfFaceName);
// FMetrics must be UTF16
  end
  else
  begin
    TempLogFontW.lfFaceName := UTF8ToUTF16(FontName);
  end;

  if TempLogFont.lfHeight = 0 then
    TempLogFont.lfHeight := FMetrics.lfMessageFont.lfHeight;

  Result := Windows.CreateFontIndirectW(@TempLogFontW);
end;

주석처리한 부분이 문제인데, FMetrics.lfMessageFont.lfFaceName 으로 들어오는 값이 '맑은 고딕' 이 아니다. Screen.SystemFont.Name 으로 수정한다.

메뉴에서 Tools -> Configure "Build Lazarus" 를 선택한후 Build 버튼을 누른다.

시스템 기본 폰트인 '맑은 고딕' 으로 라자루스 IDE 가 변한다.

변경 전

변경 후